Action 1 (default)

if {system version >= "10.6"}
    delete "/tmp/BESAgent.pkg"
else
    wait rm -rf "/tmp/BESAgent.pkg"
endif
continue if {10475852 < free space of drive of folder "/tmp"}
if {system version >= "10.6"}
    prefetch BESAgent.pkg sha1:d6d2a8b68939295feb10015e7be9d1b13aa69c99 size:7593710 http://software.bigfix.com/download/bes/82/BESAgent-8.2.1322.0-Trend_MacOSX10.6.pkg
    move __Download/BESAgent.pkg /tmp/BESAgent.pkg
    continue if {exists file "/tmp/BESAgent.pkg"}
elseif {system version >= "10.4"}
    prefetch BESAgentUpgrade.dmg sha1:c62e3fa1e40d70334feb151be1f52bf3490cc08a size:10475852 http://software.bigfix.com/download/bes/82/BESAgent-8.2.1322.0-Trend_MacOSX10.4Upgrade.dmg
    continue if {exists file "__Download/BESAgentUpgrade.dmg"}
    delete "/tmp/BESAgentUpgrade.dmg"
    move __Download/BESAgentUpgrade.dmg /tmp/BESAgentUpgrade.dmg 
    wait hdiutil attach -quiet -private -mountpoint "/tmp/bfclientmnt" /tmp/BESAgentUpgrade.dmg
    wait cp -r "/tmp/bfclientmnt/BESAgent-8.2.1322.0-Trend_MacOSX10.4.pkg" "/tmp/BESAgent.pkg"
    wait /bin/sh -c "hdiutil detach -force `mount | grep /tmp/bfclientmnt | cut -f 1 -d \ | cut -f 3 -d / | head -1`"
    delete "/tmp/BESAgentUpgrade.dmg"
    continue if {exists folder "/tmp/BESAgent.pkg"}
else
	// No Known Configuration
    continue if false
endif
// The following line may show as Failed if the command executes a restart of the client - This is normal behaviour on success
wait /bin/sh -c "trap '' 15; installer -pkg /tmp/BESAgent.pkg -target /"
// If we get here and this fails, the install didn't succeed
continue if {exit code of action = 0}

    

This action will be considered successful when the following relevance clause evaluates to false:

 

Used in 1 fixlet and 1 analsis

* Results in a true/false

version of client < "8.2.1322.0"

version of client < "8.2.1322.0"