Action 1

// Source Release Date: 2016-12-05
prefetch RESWMAgent.msi sha1:B0E7A19B6A3CB0213D44FE7384DC6412E4DA4E6D size:36743680 http://downloads.ressoftware.com/downloads/cdm/9.10.2.1/RES-ONE-Workspace-2015-Agent-SR2.msi sha256:DC24EE38A78FA7936385B5206B6EE5012A612752B7A21FE26EF5D94DC6F4B638
//remove agent if it is installed already
prefetch RES-ONE-Workspace.msi sha1:7FFF35953F335DF486BAB9B6BB7F57BC4BDD1424 size:48955392 http://downloads.ressoftware.com/downloads/cdm/9.10.2.1/RES-ONE-Workspace-2015-SR2.1.msi sha256:5462E21B7FD8EDCE6F363FA12AD0DC1D352E617F655CA441BC28443D3D0FA4F9

// action log all

//
// Validation
//

continue if {parameter "rlParent" of action != ""}
continue if {parameter "RESEnvGUID" of action != ""}
continue if {parameter "RESRELPORT" of action != ""}
continue if {parameter "RESEnvPwdHash" of action != ""}

//
// Change Action Parameter into acceptable Inheritance settings for MSI
//

if {parameter "inheritSettings" of action = "Inherit Settings"}
    parameter "inherit"="yes"
else
    parameter "inherit"="no"
endif

//
// Remove RES ONE Agent if it is installed
//

action uses wow64 redirection {not x64 of operating system}

If {exists service "res" and exists file (pathname of parent folder of parent folder of file of service "res" & "\pfwsmgr.exe")}
  If {exists values "InstallationType" whose (it as string as lowercase contains "server") of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" of native registry}
    If {exists values "InstallationType" whose (it as string as lowercase contains "core") of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" of native registry}
      regset "[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon]" "Shell"="cmd.exe /c \"cd /d \"%USERPROFILE%\" & start cmd.exe /k runonce.exe /AlternateShellStartup"
    else
      regset "[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon]" "Shell"="explorer.exe"
    EndIf
  EndIf
  waithidden cmd /C net stop "res"

  wait msiexec /x __Download\RESWMAgent.msi autoruncomposer=no remove=all reboot=R /qn
EndIf

//
// Install Console with Agent
//

if {parameter "rlParent" of action = "Current BigFix Relay"}
    parameter "CurrentRelay"="{(preceding text of first ":" of name of registration server as lowercase ) & ":" & parameter "RESRELPORT" of action}"
    parameter "ConfRelay1"="{(";" & preceding text of first ":" of following text of first "//" of value of setting "__RelayServer1" of client as string as lowercase & ":" & parameter "RESRELPORT" of action) | ""}"
    parameter "ConfRelay2"="{(";" & preceding text of first ":" of following text of first "//" of value of setting "__RelayServer2" of client as string as lowercase  & ":" & parameter "RESRELPORT" of action) | ""}"
    parameter "RelayList"="{ concatenations ";" of unique values of substrings separated by ";" of (parameter "CurrentRelay" & parameter "ConfRelay1" & parameter "ConfRelay2")}"
else
    parameter "RelayList"="{parameter "rlParent" of action}"
endif

action uses wow64 redirection true

wait msiexec /i __Download\RES-ONE-Workspace.msi RSENVGUID="{(parameter "RESEnvGUID" of action)}" RSPASSWORD="{parameter "RESEnvPwdHash" of action}" RSPWHASHED=Yes RSDISCOVER=No RSLIST="{parameter "RelayList"}" DBTYPE=MSSQL DBSERVER="{parameter "dbServer" of action}" DBNAME="{parameter "dbName" of action}" INHERITSETTINGS={parameter "INHERIT"} /qn
notify client forcerefresh