Action 1 (default)

//state of service = Continuing, Pausing, Paused, Running, Starting, Stopping, Stopped, Unknown

//if filldb is stopping and we haven't configured the stopping flag.
//this means this is the first time we've seen the filldb service in a stopping state
//we need to configure the flag so the next time this task runs, we'll be able to fix
if {state of service "FillDB" = "Stopping" AND not exists setting "FillDB_Stopping" of client}
	//set flag for next run...
    setting "FillDB_Stopping"="{now as string}" on "{now}" for client
	//every 15min this task will run again, filldb will be stopped and 
	//the flag will be set which will make it go into the next section of code
	//where we can kill the process... it shouldn't take 15min to stop.
	//if it was able to stop during the 15min wait, then the else section
	//will run which clears the flag.

elseif {state of service "FillDB" = "Stopping" AND exists setting "FillDB_Stopping" of client}
	//forcably kill the FillDB process
    waithidden cmd /c taskkill /IM FillDB.exe /F

	//if it successfully killed it, then clear the flag and restart
    if {state of service "FillDB" = "Stopped"}
		//first remove the flag...
        if {exists setting "FillDB_Stopping" of client} 
            setting delete "FillDB_Stopping" on "{now}" for client
        endif

        waithidden cmd /c net start FillDB
    endif

else
	//delete the flag under any other circomstances
    if {exists setting "FillDB_Stopping" of client} 
        setting delete "FillDB_Stopping" on "{now}" for client
    endif


	//pull old sha1 from registry and read new sha1
    parameter "LASTsha1"="{if exists setting "FillDB_PerfSha1" of client then value of setting "FillDB_PerfSha1" of client else ""}"
    parameter "NEWsha1"="{if exists value "PerformanceDataPath" of key "HKEY_LOCAL_MACHINE\SOFTWARE\BigFix\Enterprise Server\FillDB" of registry then sha1 of file (value "PerformanceDataPath" of key "HKEY_LOCAL_MACHINE\SOFTWARE\BigFix\Enterprise Server\FillDB" of registry as string) else ""}"

	//compare sha1's to see if filldb has stalled...
    if {parameter "LASTsha1" != "" AND parameter "LASTsha1" = parameter "NEWsha1"}
		//sha1 did not change, restart service
        waithidden cmd /c net stop FillDB
    else
		//save new sha1 for later use
        setting "FillDB_PerfSha1"="{parameter "NEWsha1" of action}" on "{now}" for client
    endif
    

	//if the filldb is in a stopped state, then start it now
    if {state of service "FillDB" = "Stopped"}
        waithidden cmd /c net start FillDB
    endif
endif

    

This action will be considered successful when all lines of the action script have completed successfully.